Valori

[losito84]

Ciao Ragazzi,
So che potrete aiutarmi
All'interno di un file excel (fantacalcio) avrei bisogno di trovare tutti i giocatori che hanno avuto la quotazione 1
Non so con un cerca.vert è possibile ottenere cio'
Allego il file
https://www.filedropper.com/showdownloa ... calcio2020
Non so se ho fatto tutto correttamente
Grazie

[Anthony47]

Con i dati così organizzati ci vuole per forza una macro. Esempio, da inserire in un Modulo standard del vba:

Codice: Seleziona tutto

Sub PuntiUno()
Dim wArr, I As Long, J As Long, Last1 As Long, LastA As Long
Dim OArr(), OInd As Long, SSh As Worksheet, tPoint As Single
'
Set SSh = Sheets("Foglio1")         '<<< Il foglio dei dati di partenza
tPoint = 1                          'Il punteggio da cercare
'
Last1 = SSh.Cells(1, Columns.Count).End(xlToLeft).Column
LastA = SSh.Cells(Rows.Count, "A").End(xlUp).Row
wArr = SSh.Range("A1").Resize(LastA, Last1).Value
OInd = 1
ReDim Preserve OArr(1 To 2, 1 To OInd)
For J = 2 To UBound(wArr, 2) Step 2
    For I = 1 To UBound(wArr)
        If wArr(I, J) = tPoint Then
            OArr(1, OInd) = wArr(I, J - 1)
            OArr(2, OInd) = wArr(I, J)
            OInd = OInd + 1
            ReDim Preserve OArr(1 To 2, 1 To OInd)
        End If
    Next I
Next J
'CONFIGURARE IL FOGLIO DI USCITA!!  '<<< Il foglio di Output
Sheets("Foglio2").Range("A:B").ClearContents
Sheets("Foglio2").Range("A1:B1") = Array("Nome", "Punti")
Sheets("Foglio2").Range("A2").Resize(OInd, 2) = Application.WorksheetFunction.Transpose(OArr)
MsgBox ("Completato...")
End Sub


Le istruzioni marcate <<< (specie quelle in coda!) vanno personalizzate come da commenti

Ciao